Skript cz_SosiaPomoc se musí přiřadit k NPC s ID sosia caristiana. Ta je ovšem zamknutá, takže je potřeba tento postup:

Pak už stačí jen plugin uložit.

Text samotného skriptu:

Begin cz_SosiaPomoc
short jednou

;skript uz nema smysl, tak konci
if ( jednou == -1 )
  return
endif

;hrac je v menu, proto skript nemusi bezet
if ( menumode == 1 )
  return
endif

;jestli je carodejka mrtva, nema skript smysl a konci
If ( GetDeadCount "sosia caristiana" > 0 )
  set jednou to -1
  return
endif

;jestlize se nebojuje proti barbarovi, tak se vrat na zacatek skriptu
If ( GetJournalIndex, MV_AbusedHealer != 70 )
  ;nebojuje se, protoze uz je dobojovano tak skript nema smysl
  If ( GetJournalIndex, MV_AbusedHealer > 70 )
    set jednou to -1
  endif
  return
endif

;bojuje se a barbar zemrel tak skonci skript
If ( GetDeadCount "hlormar wine-sot" > 0 )
  ;odpoj pripadne pripojenou carodejku
  if ( jednou == 1 )
    AIWander 256, 5, 0, 50, 60, 20, 10, 10, 0, 0, 0, 0
  endif
  set jednou to -1
  return
endif

;bojuje se a carodejka se jeste nepripojila
if ( jednou == 0 )
  ;a je pobliz, ze muze boj alespon slyset
  if ( GetDistance Player <= 1024 )
    set jednou to 1
    ;tak se pripoji
    AIFollow, player, 0,0,0,0,0
  endif
endif

End